//获取万科A2015年年报利润分配表的字段调整情况
  return getReportAdjustmentField("SZ000002",20151231,46);
 

Function getReportAdjustmentField(stock,rdate,infoid);
Begin
{
  说明：获取个股指定报告期财报数据的调整字段
  参数：
    stock：string 股票代码
    rdate：Int 报告期
    infoid：Int 报表InfoID
  返回：数组，发生调整的字段信息，没有调整返回空数组
}

  setsysparam(pn_reportmode(),-1);//取全部
  data:=select * from infotable infoid of stock
          where ["截止日"]=rdate end;
  if length(data)<2 then return array();

  tarr:=data[:,"公布日"];
  zhs:= nchoosek(tarr,2); //公布日分组
  data:= `NormalTabletoStrSubscript(data,"公布日");
  rt:=array();
  for j in zhs do
  begin
    info:=data;
    zh:=zhs[j,:];
    rdate1:=Max(zh[0],zh[1]);
    rdate2:=min(zh[0],zh[1]);
    sdate1:=FloatToStr(rdate1);
    sdate2:=FloatToStr(rdate2);
    dbfield:=sdate1$"-"$sdate2;
    //对比不同报告期数据
    info[:,dbfield]:=info[:,rdate1].=info[:,rdate2];
    tem:= select [rdate1],[rdate2]
       from info where [dbfield]=0 end;
    cols:=mrows(tem,1);
    rt[n,"StockID"]:=stock;
    rt[n,"StockName"]:=stockname(stock);
    rt[n,"数据表"]:=bname(infoid);
    rt[n,"截止日"]:=rdate;
    rt[n,"调整前公布日"]:=rdate2;
    rt[n,"调整后公布日"]:=rdate1;
    rt[n,"调整字段"]:=cols;
    rt[n++,"调整详情"]:=tem;
  end
  return rt;
End;